////FFT-P1-P50
mclose('all');
clear
z=struct('pfad','','name','','pfadname','','sample',0,'start1',0,'start2',0,'info',[0 0 0 0 0 0 0 0],'laufz',0,'yf',0,'yff',[0.1],'g',0,'h1',0,'h2',0,'h3',0,'h4',0,'h5',0,'g1',0,'g2',0,'g3',0,'g4',0,'g5',0,'v',1,'p50',0,'lp1',0,'lp50',0,'hs50',0,'hs1',0,'kfakt',1,'ufakt',1,'p1a',0,'form',0,'pos',0,'kalibrierwert',0,'wahlwert',70,'ti','FFT Wave und Hörschwellen','v',1,'z',0,'xp1',0,'xp50',0,'kanal',1);
///////////////////////////// Kalibrierwert einstellen /////////////////////
z.kalibrierwert=70
///////////////////////////////////////////////////////////////////////////
// 25 Hz - 0.8609938 -- 860.9938
/////////////////////////////hörschwellen bis 8000 Hz
//hs1
z.hs1=[31 42.3;40 36;50 29.8;63 24.9;80 20.9;100 17.1;125 13.3;160 9.1;200 5.5;
250 2.5;315 -0.1;400 -2.2;500 -3.8;630 -5.4;750 -6.5;800 -6.9;1000 -7.6;
1250 -7.4;1500 -9.1;1600 -9.9;2000 -13.1;2500 -15.9;3000 -17.2;3150 -17.4;
4000 -16.7;5000 -13.2;6000 -8;6300 -6.5;8000 -0.8]
//hs1 ergänzung
z.hs1e=[20 48;25 45.5;31 42.3]
//hs50
z.hs50=[20 78.5;25 68.7;31 59.5;40 51.1;50 44;63 37.5;80 31.5;100 26.5;
125 22.1;160 17.9;200 14.4;250 11.4;315 8.6;400 6.2;500 4.4;630 3;750 2.4;
800 2.2;1000 2.4;1250 3.5;1500 2.4;1600 1.7;2000 -1.3;2500 -4.2;3000 -5.8;
3150 -6;4000 -5.4;5000 -1.5;6000 4.3;6300 6;8000 12.6]
/////////////////////////////////////
function aus=fuellen(ein)
//Reihung prüfen
a=gsort(ein,'lr','i');
x=a(:,1);
y=a(:,2);
m=max(x);
if m<20001 then
l=linspace(1,m,m);
s=size(x);
for i=1:1:s(1)-1;
//
dx1=x(i);
dx2=x(i+1);
dx12=dx2-dx1;
dy1=y(i);
dy2=y(i+1);
dy12=dy2-dy1;
yz=dy1:dy12/dx12:dy2;
l(x(i):x(i+1))=yz;
end
end
aus=l;
endfunction
////////////////////////Hörschwelle p1
//vervollständigung der Hörschwelle
z.xp1=linspace(1,8000,8000);
e=fuellen(z.hs1);
z.xp1=e;
//umrechnen von dB in linear auf 70 dB obergrenze
e=z.xp1-70;
e=e./20;
e=10^e;
z.lp1=e;
////////////////////////Hörschwelle p1e ergänzung
//vervollständigung der Hörschwelle
z.xp1=linspace(1,31,31);
e=fuellen(z.hs1e);
z.xp1e=e;
//umrechnen von dB in linear auf 70 dB obergrenze
e=z.xp1e-70;    
e=e./20;
e=10^e;
z.lp1e=e;
///////////////////////Hörschwelle p50
//vervollständigung der Hörschwelle
z.xp50=linspace(1,8000,8000);
e=fuellen(z.hs50);
z.xp50=e;
//umrechnen von dB in linear auf 70 dB obergrenze
e=z.xp50-70;
e=e./20;
e=10^e;
z.lp50=e;
///////////////
//verstärkung
a=1:1:10;
a=a./20;
a=10^a;
z.z(1)=1;
z.z(2:11)=a;
////////////////////////////////
function [z]=neu(z)
//////////////////////////////////////////////////////////////////////////////
//disp(z.h1)
if z.g1 ==0 then else delete(z.g1);z.g1=0; end;
if z.g2 ==0 then else delete(z.g2);z.g2=0; end;
if z.g3 ==0 then else delete(z.g3);z.g3=0; end;
if z.g4 ==0 then else delete(z.g4);z.g4=0; end;
if z.g5 ==0 then else delete(z.g5);z.g5=0; end;
// WAV Datei auswählen   
[z.name,z.pfad]=uigetfile('*.wav','D:\Mdaten');    //WAV Datei wählen
if isequal(z.name,'');    //Ist eine Date gewählt?
    else
z.pfadname=z.pfad+'\'+z.name;  //Vollständigen Pfad erstellen 
z.info = wavread(z.pfadname,'info');  //WAV Info`s laden
disp('//////////////////////////////////////////////////////////')
disp('WAV-Datei: '+z.pfadname); //Ausgabe vollständiger Pfad
disp('Kanäle: '+string(z.info(2)));   //Ausgabe Anzahl der Kanäle
disp('Samplerate: '+string(z.info(3)));   //Ausgabe Samplerate
disp('Dateilänge : '+string(z.info(8)));    //Ausgabe Dateilänge
disp('Laufzeit : '+string(z.info(8)/z.info(3))+' Sekunden');    //Laufzeit in Sek.
disp('//////////////////////////////////////////////////////////')
z.pfaddat=strsplit(z.pfadname,'.');
z.laufz=floor(z.info(8)/z.info(3)); // lauzeit in sekunden
z.sample=z.info(3); //Samplerate der Audiodatei
z.h1.data_bounds(2,1)=z.sample;//fenster oben x achse
if z.info(2)==2 then
set(u18,'string','2 Kanal')
z.kanal=2
else
set(u18,'string','1 Kanal')
z.kanal=1
end
//faktor berechnen
a=70-z.kalibrierwert;
a=a/20;
a=10^a;
a=1/a;
z.kfakt=a;
///////
set(u16,'string',z.pfadname);
z.start1=1;
z.start2=z.sample;
z.pos=1;
set(u3,'string',string(z.laufz));
set(u4,'max',z.laufz);
set(u4,'min',1);
[z]=rechenwerk(z);
[z]=achseoben(z); 
[z]=achseunten(z); 
end
endfunction
////////////////////////////////////////////////////////////////////////////
function [z]=rechenwerk(z)
    //
if  z.start2 < z.info(8) then 
z.yf=wavread(z.pfadname,[z.start1 z.start2]); 
z.yf=z.yf(z.kanal,:);
z.yf=z.yf*z.v;
////
z.yff=fft(z.yf,-1,'nonsymmetric'); //Die FFT wird berechnen
z.yff=z.yff/z.sample;
z.g=z.yff(1);
z.yff=abs(z.yff(2:8000));
z.yff=z.yff*2000;
//eingangssignal
a=abs(z.yf);
a=sum(a);
a=a/z.sample;//arithmetischer mittelwert
c=a*1.5708187;
b=a*1.111;
set(u31,'string',string('  '+string(a)+ '  Gleichrichtwert'));
set(u32,'string',string('  '+string(b)+ '  Effektivwert'));
set(u33,'string',string('  '+string(c)+ '  Amplitude'));
////
end;
endfunction
///////////////////////////////////////////////////////////////////////7/////
function [z]=achseoben(z)
sca(z.h1);
if z.g1 ==0 then else delete(z.g1);z.g1=0; end;// wav signal
if z.g2 ==0 then else delete(z.g2);z.g2=0; end; // fft signal
if z.g3 ==0 then else delete(z.g3);z.g3=0; end; // p50 signal
if z.g4 ==0 then else delete(z.g4);z.g4=0; end; // p1 signal
if z.g5 ==0 then else delete(z.g5);z.g5=0; end; // p1e signal
z.h1.x_ticks=tlist(['locations','labels'],[0,z.sample*0.1,z.sample*0.2,z.sample*0.3,z.sample*0.4,z.sample*0.5,z.sample*0.6,z.sample*0.7,z.sample*0.8,z.sample*0.9,z.sample*1],[string(z.pos+0),string(z.pos+0.1),string(z.pos+0.2),string(z.pos+0.3),string(z.pos+0.4),string(z.pos+0.5),string(z.pos+0.6),string(z.pos+0.7),string(z.pos+0.8),string(z.pos+0.9),string(z.pos+1)]);
plot([1:z.sample],z.yf,'red');//,'thickness',3);
z.g1=gce();
////////////////////////
endfunction
///////////////////////////////////////////////////////////////////////////
function [z]=achseunten(z)
//
if z.g2 ==0 then else delete(z.g2);z.g2=0; end;
if z.g3 ==0 then else delete(z.g3);z.g3=0; end;
if z.g4 ==0 then else delete(z.g4);z.g4=0; end;
if z.g5 ==0 then else delete(z.g5);z.g5=0; end;
sca(z.h2); 
a=z.yff*z.kfakt*z.ufakt;
//plot(a,'blue','thickness',3);
plot2d(a);
z.g2=gce()
//
a=z.lp50*1000*z.kfakt*z.ufakt
//plot([20:8000],a(20:8000),'green','thickness',3);
plot2d([20:8000],a([20:8000]));
z.g3=gce()
//
a=z.lp1*1000*z.kfakt*z.ufakt
//plot([31:8000],a(31:8000),'red','thickness',3);
plot2d([31:8000],a([31:8000]))
z.g4=gce()
//
a=z.lp1e*1000*z.kfakt*z.ufakt
//plot([20:31],a(20:31),'magenta','thickness',3);
plot2d([20:31],a([20:31]));
z.g5=gce()
b=gca();
b.children.children(1).thickness=3;
b.children.children(1).foreground=color('magenta');
b.children.children(2).thickness=3;
b.children.children(2).foreground=color('red');
b.children.children(3).thickness=3;
b.children.children(3).foreground=color('green');
b.children.children(4).thickness=3;
b.children.children(4).foreground=color('blue');
//
legend(['FFT - Wave';'Hörschwelle P50 DIN';'Hörschwelle P1';'Hörschwelle P1 Schätzung']);
///////////////////////////////////////////////////////////////////////
endfunction
//////////////////////////////////////////////////////////////////////

//////////////////////////////////////////////////////////////////////
function [z]=position(z)
//
if z.pos>1 then
//
if z.pos<z.laufz+1 then
//
if z.g1 ==0 then else delete(z.g1);z.g1=0; end;
if z.g2 ==0 then else delete(z.g2);z.g2=0; end;
if z.g3 ==0 then else delete(z.g3);z.g3=0; end;
if z.g4 ==0 then else delete(z.g4);z.g4=0; end;
if z.g5 ==0 then else delete(z.g5);z.g5=0; end;
z.start1=(z.pos-1)*z.sample+1;
z.start2=z.pos*z.sample;
[z]=rechenwerk(z);
[z]=achseoben(z); 
[z]=achseunten(z); 
end
end
endfunction
///////////////////////////////////////////////////////////////////
function [z]=zoom(z)
//
if u6.value==1 then
z.h2.zoom_box=[0,0,250,100];
else
unzoom(z.h2);
end
endfunction
////////////////////////////////////////////////////////
function [z]=umsch(z)
//
if z.g3 ==0 then else delete(z.g3);z.g3=0; end;
if z.g4 ==0 then else delete(z.g4);z.g4=0; end;
if z.g5 ==0 then else delete(z.g5);z.g5=0; end;
if u5.value==0 then
z.ufakt=1;
z.wahlwert=70;
else
z.ufakt=10;
z.wahlwert=50;
end
z.h2.y_ticks=tlist(['locations','labels'],[1000,562,316,177,100,56,31,17,5],[string(z.wahlwert),"-5","-10","-15","-20","-25","-30","-35","-40"]);
[z]=achseunten(z)
endfunction
///////////////////////////////////////////////////////////
function [z]=verstaerkung(z)
//
a=u21.value;
a=a+1;
z.v=z.z(a);
[z]=rechenwerk(z);
[z]=achseoben(z); 
[z]=achseunten(z); 
endfunction
////////////////////////////////////////////////////////////
function [z]=kanal(z)
//
a=z.info(2);
select a
case 0 //keine datei gewält
set(u17,'value',0); // auf anfang setzen
z.kanal=1; // auf anfang setzen
case 1 //eine datei wurde gewählt
set(u17,'value',0); // auf anfang setzen
z.kanal=1; // auf kanal 1 setzen
[z]=rechenwerk(z);
[z]=achseoben(z); 
[z]=achseunten(z); 
case 2
b=u17.value; // nun schalter abfragen
if b==0 then
set(u17,'value',0); // auf anfang setzen
z.kanal=1; // auf anfang setzen
[z]=rechenwerk(z);
[z]=achseoben(z); 
[z]=achseunten(z); 
else
set(u17,'value',1); // auf kanal 2 setzen
z.kanal=2; // auf kanal2 setzen
[z]=rechenwerk(z);
[z]=achseoben(z); 
[z]=achseunten(z); 
end  
end 
endfunction
////////////////////////////////////////////////////////
function[z]=savgif1(z)
//
if z.pfadname=='' then
else
zd=getdate();
zs=z.pfaddat(1)+'_'+string(zd(1))+'-'+string(zd(2))+'-'+string(zd(6))+'_'+string(zd(7))+'-'+string(zd(8))+'-'+string(zd(9))+'.gif';
//xs2gif(gcf(),zs);
xs2gif(z.form,zs);
end
endfunction
/////////////////////////////////////////////////////////////
function [z]=titeledit(z)
//
z.ti=x_dialog('Titel eingeben',z.ti);
title(z.ti,'fontsize',3);
endfunction
/////////////////////////////////////////////////////////////
function [z]=botschaft(z)
//
b1='Hallo'
b2='Bei den Aufnahmen verwende ich den mobilen Sony Recorder PCM-M10. Bei höchster Empfindlichkeit und voll ausgesteuert ist am Mikrofon ein maximaler Schallpegel von etwa 70 dB vorhanden. '
b3='Dieser Wert wird bei den Berechnungen als Kalibrierwert zu Grunde gelegt. Die Analysen zeigen wie die FFT Schallpegel an die Hörschwellen P1 und P50 heranreichen. '
b4='So ist ersichtlich wie das Hören von tieffrequenten Geräuschen möglich ist. Sie können den Kalibrierwert des von Ihnen verwendeten Aufnahmegerätes ermitteln und den gemessenen'
b5='Kalibrierwert in das Rechenprogramm einfügen. Der neue Kalibrierwert wird in der Programmzeile 6 eintragen. Dort steht z.kalibrierwert = 70. Sie müssen den Wert 70 durch den von Ihnen'
b6='ermittelten Wert ersetzen. Zur Ermittlung des Kalibrierwertes habe ich den Sonyrecorder vor einem Lautsprecher aufgebaut und den Lautsprecher mit 1000 Hz soweit aufgedreht bis der'
b7='Recorder voll aussteuert ist. Dann habe ich mit dem Schallpegelmesser unmitelbar am Mikrofon des Recorders den Schallpegel bei 1000Hz gemessen. ' 
b8='Etwa 1% der Bevölkerung haben die biologische Hörschwelle P1. Die blaue Linie ist die nach DIN festgelegte Hörschwelle P50, diese wird bei Schallpegelmessungen zu Grunde gelegt.' 
b9='Mindestens 1% der Bevölkerung haben die Hörschwelle P1 und können tiefe Tongeräusche aus der Umwelt besonders gut hören und sind deshalb von dem Brummton besonders betroffen'
b10='B I T T E----B E A C H T E N----D I E----A N G E Z E I G T E N----W E R T E----S I N D----N U R----S C H Ä T Z W E R T E----U N D----K  E I N----E R S A T Z----F Ü R----P R O F E S S I O N E L L E----M E S S U N G E N !'
c1=[b2 b3 b4 b5 b6 b7 b8 b9 b10]
a=messagebox([b1 c1],'Kalibrierung ändern?','info',["No" "Yes"],'modal')
if a==2 then
//
scinotes('FFT-P1-P50.sce',6);
close
end
endfunction
/////////////////////////////////////////////////////////////
// formular
////////////////////////////////////////////////////////////
z.form=gcf();//
z.form.color_map = jetcolormap(1000); //Colormap festlegen
z.form.visible = "on";
z.form.figure_position = [20,20];
z.form.figure_size = [1400,900];
z.form.figure_name="Wav - Zeit- Frequenz - FFT - Analyse";
z.form.BackgroundColor=[1 1 1];
z.form.tag='Formular';
///////////////////////////////////////////////////////////
///achse 1
z.h1 = newaxes(); // 
z.h1.axes_bounds = [-0.09,0,1.1,0.2];
z.h1.visible = "on";
z.h1.axes_visible = ["on","on","on"];
z.h1.axes_reverse = ["off","off","off"];
z.h1.auto_ticks = ["off","off","off"];

z.h1.grid = [1,1];
z.h1.grid_thickness = [1,1];
z.h1.grid_style = [1,1];
z.h1.grid_position = "background";

z.h1.title.font_size=2;
z.h1.title.text="WAV Eingangssignal 1 Sek.";
z.h1.x_label.font_size=2;
z.h1.x_label.text="";
z.h1.x_label.visible="on";
z.h1.y_label.font_size=2;
z.h1.y_label.text="Amplitude";
z.h1.y_label.visible="on";


z.h1.auto_scale="off";
// zeitachse
z.h1.x_ticks=tlist(['locations','labels'],[0,z.sample*0.1,z.sample*0.2,z.sample*0.3,z.sample*0.4,z.sample*0.5,z.sample*0.6,z.sample*0.7,z.sample*0.8,z.sample*0.9,z.sample*1],[string(z.pos+0),string(z.pos+0.1),string(z.pos+0.2),string(z.pos+0.3),string(z.pos+0.4),string(z.pos+0.5),string(z.pos+0.6),string(z.pos+0.7),string(z.pos+0.8),string(z.pos+0.9),string(z.pos+1)]);
// amplitudenachse
z.h1.y_ticks=tlist(['locations','labels'],[1,0.5,0,-0.5,-1],["1","0.5","0","-0.5","-1"]);
z.h1.sub_tics=[9,4,9];
z.h1.box = "back_half";
z.h1.background = -2;
z.h1.tight_limits = ["on","on"];
z.h1.cube_scaling = "off";
// mit den folgenden einstellungen der drei achsen kann die Anzeige angepasst werden 
/////////////////////////////////////////////////////////////////////////////
z.h1.isoview = "off";
z.h1.auto_margins = "off"
z.h1.margins = [0.05,0.1,0.05,0.8]
z.h1.axes_bounds = [0,0,1,1]
z.h1.x_location = "bottom"
z.h1.y_location = "left"

zh=z.h1.data_bounds;
zh(1,2)=-1;
zh(2,2)=1;
zh(1,1)=0;
zh(2,1)=48000;
z.h1.data_bounds =zh;
z.h1.tag='Oben';
///////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////
///achse 2
z.h2 = newaxes(); // 
// []
z.h2.axes_bounds = [0,0,0.81,1];
z.h2.visible = "on";
z.h2.axes_visible = ["on","on","on"];
z.h2.axes_reverse = ["off","off","off"];
z.h2.auto_ticks = ["off","off","off"];

z.h2.grid = [1,1];
z.h2.grid_thickness = [1,1];
z.h2.grid_style = [1,1];
z.h2.grid_position = "background";

z.h2.title.font_size=2;
z.h2.title.text="FFT Wave und Hörschwellen";
z.r.x_label.font_size=2;
z.h2.x_label.text="Frequenz";
z.h2.x_label.visible="on";
z.h2.y_label.font_size=2;
z.h2.y_label.text="Amplitude";
z.h2.y_label.visible="on";

z.h2.auto_scale="off";
// frequenzaschse
z.h2.x_ticks=tlist(['locations','labels'],[0,50,100,150,200,250,300,350,400,450,500,550,600,650,700,750,800,850,900,950,1000,1050,1100,1150,1200,1250],["0","50","100","150","200","250","300","350","400","450","500","550","600","650","700","750","800","850","900","950","1000","1050","1100","1150","1200","1250"]);
// amplitudenachse
z.h2.y_ticks=tlist(['locations','labels'],[1000,562,316,177,100,56,31,17,5],[string(z.wahlwert),"-5","-10","-15","-20","-25","-30","-35","-40"]);

z.h2.sub_tics=[9,4,9];

z.h2.box = "back_half";
z.h2.background = -2;
z.h2.tight_limits = ["on","on"];
z.h2.cube_scaling = "off";
z.h2.isoview = "off";
z.h2.log_flags = "nnn"
z.h2.auto_margins = "on"
//z.h2.margins = [0.05,0.1,0.3,0.1]
z.h2.margins = [0.05,0.1,0.27,0.06]
z.h2.x_location = "bottom"
z.h2.y_location = "left"
z.h2.axes_bounds = [0,0,1,1]

// mit den folgenden einstellungen der drei achsen kann die Anzeige angepasst werden 
/////////////////////////////////////////////////////////////////////////////
zh=z.h2.data_bounds;
zh(1,2)=0;
zh(2,2)=1000;
zh(1,1)=0;
zh(2,1)=1250;
z.h2.data_bounds =zh;
z.h2.tag='Unten';
///////////////////////////////////////////////////////////////////////
// controls

//verstärkung
u20=uicontrol(z.form,"style","text",'Relief','flat','HorizontalAlignment','center' ,'position', [1290 660 80 20],'string','Verstärkung dB','callback','');
//
u21=uicontrol(z.form,"style","spinner",'position', [1290 620 80 30],'Relief','raised','HorizontalAlignment','left','VerticalAlignment','bottom','min',0,'max',10,'SliderStep',[1,10],'callback','[z]=verstaerkung(z)');
//kalibrieren
u1=uicontrol(z.form,"style","pushbutton",'Relief','raised','HorizontalAlignment','center' ,'position', [1290 718 80 20],'string','Info','callback','[z]=botschaft(z)');
//überschrift
u2=uicontrol(z.form,"style","text",'Relief','flat','HorizontalAlignment','center' ,'position', [1290 520 80 20],'string','Max Laufzeit','callback','');
// maxposition
u3=uicontrol(z.form,"style","text",'Relief','flat','HorizontalAlignment','center' ,'position', [1290 490 80 20],'string','0','callback','');
//position
u4=uicontrol(z.form,"style","spinner",'position', [1290 440 80 40],'Relief','raised','HorizontalAlignment','left','VerticalAlignment','bottom','min',0,'max',0,'SliderStep',[1,10],'callback','z.pos=u4.value;[z]=position(z)');
//umschalten
u5=uicontrol(z.form,"style","radiobutton",'Relief','raised','HorizontalAlignment','left' ,'position', [1290 340 80 20],'string','70/50 dB','callback','[z]=umsch(z)');
//zoom
u6=uicontrol(z.form,"style","radiobutton",'Relief','raised','HorizontalAlignment','left' ,'position', [1290 310 80 20],'string','Zoom','callback','[z]=zoom(z)');
//Titeledit
u7=uicontrol(z.form,"style","pushbutton",'Relief','raised','HorizontalAlignment','center' ,'position', [1290 270 80 20],'string','Titel Edit','callback','[z]=titeledit(z)');
//savegrafik
u8=uicontrol(z.form,"style","pushbutton","Relief", "raised",'HorizontalAlignment','center' ,'position', [1290 230 80 20],'string','Save Grafik','callback','[z]=savgif1(z)');
//neu
u9=uicontrol(z.form,"style","pushbutton",'Relief','raised','HorizontalAlignment','center' ,'position', [1290 60 80 20],'string','Neu','callback','[z]=neu(z)');
//schließen
u10=uicontrol(z.form,"style","pushbutton",'Relief','raised','HorizontalAlignment','center' ,'position', [1290 20 80 20],'string','Exit','callback','close');
//Datei
u16=uicontrol(z.form,"style","text",'HorizontalAlignment','left' ,'position', [70 740 490 20],'string',z.pfadname);
//kanalwahl
u17=uicontrol(z.form,"style","radiobutton",'Relief','raised','HorizontalAlignment','left' ,'position', [1290 370 80 20],'string','Kanal 1 / 2','callback','[z]=kanal(z)');
u18=uicontrol(z.form,"style","text",'HorizontalAlignment','center' ,'position', [1290 400 80 20],'string','1 Kanal');
//info wav signal
u30=uicontrol(z.form,"style","text",'HorizontalAlignment','left' ,'position', [750 740 55 20],'string','  Bei Sinus');
u31=uicontrol(z.form,"style","text",'HorizontalAlignment','left' ,'position', [810 740 150 20],'string','');
u32=uicontrol(z.form,"style","text",'HorizontalAlignment','left' ,'position', [965 740 140 20],'string','');
u33=uicontrol(z.form,"style","text",'HorizontalAlignment','left' ,'position', [1110 740 130 20],'string','');
u34=uicontrol(z.form,"style","text",'HorizontalAlignment','center' ,'position', [1290 740 80 20],'string','  1 = '+string(z.kalibrierwert)+'  dB');
//
//
//
u999a=uicontrol(z.form,"style","text",'backgroundcolor',[0.1 1 0.8],'position', [1246 733 47 2],'string','');

[z]=achseunten(z)
/////////////////////////////////


//
//