// 3d-WAV-Analyse20-1
// WAV Dateien mit Abtastfrequenzen von 22005 und 96000 Hz können genutzt werden
// Vermutlich können auch Dateien mit anderen Abtastfrequenzen genutzt werden.
// Abtastfrequenzen von 22000 bis 96000 sind möglich. Ich bevorzuge 48000.
// Es werden FFT Frequenzen von 1 bis 250 Hz berechnet
// Es werden Zeitabschnitte von 30,60,120,240 und 480 Sekunden berechnet
// Das Signal kann von 1 bis 10 verstärkt werden
// Es kann zwischen Kanal 1 und Kanal 2 gewechselt werden
// Es wird im Textfeld Position Sek. die Laufzeit der WAV Datei angezeigt
// Die Start-Position des zu berechnenden Abschnittes wird mit dem Zähler ausgewählt
// Es kann zwischen FFT Darstellung und Power Darstellung gewählt werden
// Es kann die Grafik Anzeige auf der Frequenz Achse gezoomt werden 
// Die Zoomfrequenz kann mit dem Zähler eingestellt werden
// Mit der Taste Zoom Grafik wird die eingestellte Zoom Frequenz aktiviert
// Mit der Taste Titel Edit kann für die Grafik eine Überschrift erstellt werden
// Mit der Taste Save Grafik wird die angezeigte Grafik in einer gif Datei gespeichert
// Mit der Taste Start werden alle oben eingestellten Voreinstellungen aktiviert und neu berechnet

// mit der Playposition wird ein Startpunkt ausgewählt und eine Sequenz 
// von 10 Sekunden Länge wird von diesem Startpunkt an abgespielt

// Mit der Taste Neu wird eine neue WAV Datei ausgewählt
// Nit der Taste Exit wird die Sitzung beendet
/////////////////////////////////////////////////////////////////////////////
mclose('all');
clear;
xdel();
z=struct('pfad','','datei','','pfaddatei','','info','','laufzeit',0,'samplerate',0,'ueberdeckung',0,'gleich',0,'posi',0,'start1',0,'start2',0,'wa',0,'ff',0,'power',0,'aaff',0,'aapp',0,'fo1',250,'spiel1',0,'spiel2',0,'a1',0,'a2',0,'a3',0,'b1',0,'b2',0,'b3',0,'h1',0,'graph1',0,'graph2',0,'f',0,'cm',0,'kanal',1,'verstaerkung',1,'darst',1,'xa','','ti','','n',0,'i',0,'u',0,'uliste','');
/////////////////////////////////////////////////////////////////////////////
function [z]=neu(z)
//////////////////////////////////////////////////////////////////////////////
// WAV Datei auswählen  
[z.datei,z.pfad]=uigetfile('*.wav','D:\Mdaten');    //WAV Datei wählen
if isequal(z.datei,'');    //Ist eine Date gewählt?
    else
z.pfaddatei=z.pfad+'\'+z.datei;  //Vollständigen Pfad erstellen 
z.info = wavread(z.pfaddatei,'info');  //WAV Info`s laden
disp('//////////////////////////////////////////////////////////')
disp('WAV-Datei: '+z.pfaddatei); //Ausgabe vollständiger Pfad
disp('Kanäle: '+string(z.info(2)));   //Ausgabe Anzahl der Kanäle
disp('Samplerate: '+string(z.info(3)));   //Ausgabe Samplerate 
disp('Dateilänge : '+string(z.info(8)));    //Ausgabe Dateilänge
disp('Laufzeit : '+string(z.info(8)/z.info(3))+' Sekunden');    //Laufzeit in Sek.
disp('//////////////////////////////////////////////////////////')
z.pfaddat=strsplit(z.pfaddatei,'.')
z.laufzeit=floor(z.info(8)/z.info(3)); // lauzeit in sekunden
if z.laufzeit<30 then;
    warning('Die WAV Datei muss mindestens 30 Sekunden Laufzeit haben')
else
z.fo1=250; //oberfrequenz der fft
z.samplerate=z.info(3); //Samplerate der Audiodatei
//verstärkung
set(u22,'string','1');
set(u23,'value',1);
//kanalwahl
set(u33,'max',z.info(2));
set(u32,'string','1');
set(u33,'value',1);
//position
set(u42,'string',string(z.laufzeit));
set(u43,'value',0);
//darstellung
set(u47,'value',1);
//überdeckung
set(u62,'string',z.uliste(1));
set(u63,'value',1);
//samplefrequenz
set(u65,'string',string(z.samplerate));
//playposition
set(u72,'max',z.laufzeit-10);
set(u72,'value',0);
//dateianzeige
set(u81,'string',string(z.pfaddatei));
z.ti=z.datei;
//'93,75 %     30s|87,5 %       60s|75 %        120s|50 %        240s|0 %          480s'
if z.laufzeit > 29 then set(u63,'value',1);
set(u63,'string',z.uliste(1));
set(u63,'value',1) 
set(u62,'string','93,75 %     30s');
else
warning('Die WAV Datei muss mindestens 30 Sekunden Laufzeit haben')
abort
end
if z.laufzeit > 59 then 
set(u63,'string',z.uliste(1:2)');
set(u63,'value',2)
set(u62,'string',z.uliste(2));
end;
//
if z.laufzeit > 119 then 
set(u63,'string',z.uliste(1:3));
set(u63,'value',3) 
set(u62,'string',z.uliste(3));
end;
//
if z.laufzeit > 239 then 
set(u63,'string',z.uliste(1:4));
set(u63,'value',4) 
set(u62,'string',z.uliste(4));
end;
//
if z.laufzeit > 479 then 
set(u63,'string',z.uliste(1:5));
set(u63,'value',5) 
set(u62,'string',z.uliste(5));
end;
z.u=u63.value;
select z.u
case 5
set(u43,'max',z.laufzeit-480);
z.i=1;
case 4
set(u43,'max',z.laufzeit-240);
z.i=2;
case 3
set(u43,'max',z.laufzeit-120);
z.i=4;
case 2
set(u43,'max',z.laufzeit-60);
z.i=8;
case 1
set(u43,'max',z.laufzeit-30);
z.i=16;
end
//
z.start1=1;
z.start2=z.samplerate;
//
[z]=rechenwerk(z)
[z]=malen0(z)
[z]=achsenx1(z)
end
end
endfunction
/////////////////////////////////////////////////////////////////////////////
function [z]=rechenwerk(z)// rechenwerk
// FFT berechnen
z.n=480;
z.w=window('hn',z.samplerate); // fft window
z.kanal=u33.value;
////////////////////////////////////////////////////////////////////////
z.gleich=0;
i=z.i
z.ueberdeckung=floor(z.samplerate/i);
ii=z.n-i+1;
iii=1;
winId=waitbar('Berechne FFT - und Leistungsspektren');
while iii-1<ii
//
waitbar(iii/ii,winId);
//
z.wa=wavread(z.pfaddatei,[z.start1 z.start2]); 
z.wa=z.wa(z.kanal,:);//kanalwahl
z.wa=z.wa*z.verstaerkung;// verstärkung
//
z.wa=z.wa.*z.w;//windows anwenden
z.ff=fft(z.wa,-1,'nonsymmetric'); //Die FFT wird berechnen
z.ff=z.ff/z.samplerate;
z.gleich=z.gleich+z.ff(1);
z.ff=abs(z.ff(2:z.samplerate));
// powerspektrum
z.power=abs(z.ff.* conj(z.ff));   //Powerspektrum der FFT berechnen
z.power=z.power(1:z.fo1);
z.ff=z.ff(1:z.fo1);
// normieren
z.ff=z.ff*4000;// normieren
z.power=z.power*4000;// normieren
z.aaff(iii,1:z.fo1)=z.ff(1:z.fo1); // fft daten
z.aapp(iii,1:z.fo1)=z.power(1:z.fo1); // leistungsdaten
z.start1=z.start1+z.ueberdeckung;
z.start2=z.start2+z.ueberdeckung;
iii=iii+1
end
close(winId);
/////auffüllen
xy=zeros(1,z.fo1);
while ii<481
z.aaff(ii,:)=xy;
z.aapp(ii,:)=xy;
ii=ii+1
end
z.gleich=z.gleich*2/ii;
//////////////////////////////////////////////////////////////////////////
set(u82,'string',' Gleichspannungsanteil  '+msprintf('%1.6f',z.gleich)); // dateiname ins formular
w=size(z.aaff);  //Größe des Array ermitteln
fx=1:1:w(1);   //X-Achse zum ploten aufbauen 
fy=1:1:w(2);   //Y-Achse zum ploten aufbauen
//
[z.a1,z.a2,z.a3]=genfac3d(fx,fy,z.aaff(fx,fy));   //Plot fft
[z.b1,z.b2,z.b3]=genfac3d(fx,fy,z.aapp(fx,fy));   //Plot leistung
///
endfunction
////////////////////////////////////////////////////////////////////////////
function [z]=malen0(z)
//
//[z]=achsenx1(z)
select z.darst
case 1
    [z]=malen1(z)
case 2
    [z]=malen2(z)
end
endfunction
/////////////////////////////////////////////////////////////////////////////
function [z]=malen1(z)
// graph 1
if z.graph1 ==0 then else delete(z.graph1);z.graph1=0; end;
z.h1.visible = "on";
sca(z.h1);
plot3d1(z.a1,z.a2,list(z.a3,z.a3),theta=-20,alpha=16,flag=[-1,2,3])
z.graph1=gce();  
z.h1.axes_visible = ["on","on","on"];
////////////////////////////////////////////////////////////////////////////
endfunction
/////////////////////////////////////////////////////////////////////////
function [z]=malen2(z)
// graph 1
if z.graph1 ==0 then else delete(z.graph1);z.graph1=0; end;
z.h1.visible = "on";
sca(z.h1);
plot3d1(z.b1,z.b2,list(z.b3,z.b3),theta=-20,alpha=16,flag=[-1,2,3])
z.graph1=gce();  
z.h1.axes_visible = ["on","on","on"];
////////////////////////////////////////////////////////////////////////////
endfunction
//////////////////////////////
function [z]=kanal(z)
    if u1.value==z.kanalzahl  then
    else
        z.kanal=u1.value;
    end
endfunction
////////////////////////////////////////////////////////////////////////////
function[z]=savgif1(z)
//
if z.pfaddatei=='' then
else
zd=getdate();
zs=z.pfaddat(1)+'_'+string(zd(1))+'-'+string(zd(2))+'-'+string(zd(6))+'_'+string(zd(7))+'-'+string(zd(8))+'-'+string(zd(9))+'.gif';
xs2gif(gcf(),zs);
end
endfunction
////////////////////////////////////////////////////////////////////
function [z]=starten1(z)
//
if z.pfaddatei=='' then
else
z.h1.zoom_box=[0,0,480,u52.value];
if z.graph1 ==0 then else delete(z.graph1);z.graph1=0; end;
//verstärkung
z.verstaerkung=u23.value;
set(u22,'string',string(z.verstaerkung));
//kanalwahl
z.kanal=u33.value;
set(u32,'string',string(z.kanal));
//überdeckung
z.u=u63.value;
select z.u
case 5
set(u43,'max',(z.laufzeit-480));
if u43.value>u43.max then set(u43,'value',u43.max) end;
set(u62,'string',z.uliste(5))
z.i=1;
case 4
set(u43,'max',(z.laufzeit-240));
if u43.value>u43.max then set(u43,'value',u43.max) end;
set(u62,'string',z.uliste(4))
z.i=2;
case 3
set(u43,'max',(z.laufzeit-120));
if u43.value>u43.max then set(u43,'value',u43.max) end;
set(u62,'string',z.uliste(3))
z.i=4;
case 2
set(u43,'max',(z.laufzeit-60));
if u43.value>u43.max then set(u43,'value',u43.max) end;
set(u62,'string',z.uliste(2))
z.i=8;
case 1
set(u43,'max',(z.laufzeit-30));
if u43.value>u43.max then set(u43,'value',u43.max) end;
set(u62,'string',z.uliste(1))
z.i=16;
end
z.posi=u43.value;
z.start1=z.posi*z.samplerate;
z.start2=z.start1+z.samplerate;
z.start1=z.start1+1;
[z]=rechenwerk(z)
[z]=malen0(z)
[z]=achsenx1(z)
end
endfunction
///////////////////////////////////////////////////////////////////////
function [z]=abspielen(z)
//
z.spiel1=(u72.value)*z.samplerate;
z.spiel2=wavread(z.pfaddatei,[z.spiel1+1 z.spiel1+z.samplerate*10]);
z.spiel2=z.spiel2(z.kanal,:);
z.spiel2=z.spiel2*z.verstaerkung;
playsnd(z.spiel2,z.samplerate);
endfunction
///////////////////////////////////////////////////////////////////////////
function [z]=achsenx1(z)
//
//z.xa=["0","5","10","15","20","25","30",'35','40','45','50','55','60']
i=z.u;
select i
case 1 //30
z.xa=[string(z.posi),string(z.posi+5),string(z.posi+10),string(z.posi+15),string(z.posi+20),string(z.posi+25),string(z.posi+30)];
z.h1.x_ticks=tlist(['locations','labels'],[0,80,160,240,320,400,480],[z.xa]);
//////////
z.h1.z_ticks=tlist(['locations','labels'],[0,100,200,300,400,500,600,700,800,900,1000],["0","0.1","0.2","0.3","0.4","0.5","0.6","0.7","0.8","0.9","1"+' V= '+string(z.verstaerkung)]);
//
set(u72,'value',z.posi); // laufzeitwert value in formular play spinner

case 2 //60
z.xa=[string(z.posi),string(z.posi+5),string(z.posi+10),string(z.posi+15),string(z.posi+20),string(z.posi+25),string(z.posi+30),string(z.posi+35),string(z.posi+40),string(z.posi+45),string(z.posi+50),string(z.posi+55),string(z.posi+60)];
z.h1.x_ticks=tlist(['locations','labels'],[0,40,80,120,160,200,240,280,320,360,400,440,480],[z.xa]);
//////////
z.h1.z_ticks=tlist(['locations','labels'],[0,100,200,300,400,500,600,700,800,900,1000],["0","0.1","0.2","0.3","0.4","0.5","0.6","0.7","0.8","0.9","1"+' V= '+string(z.verstaerkung)]);
//
set(u72,'value',z.posi); // laufzeitwert value in formular play spinner

case 3 //120
z.xa=[string(z.posi),string(z.posi+10),string(z.posi+20),string(z.posi+30),string(z.posi+40),string(z.posi+50),string(z.posi+60),string(z.posi+70),string(z.posi+80),string(z.posi+90),string(z.posi+100),string(z.posi+110),string(z.posi+120)];
z.h1.x_ticks=tlist(['locations','labels'],[0,40,80,120,160,200,240,280,320,360,400,440,480],[z.xa]);
//////////
z.h1.z_ticks=tlist(['locations','labels'],[0,100,200,300,400,500,600,700,800,900,1000],["0","0.1","0.2","0.3","0.4","0.5","0.6","0.7","0.8","0.9","1"+' V= '+string(z.verstaerkung)]);
//
set(u72,'value',z.posi); // laufzeitwert value in formular play spinner

case 4 //240
z.xa=[string(z.posi),string(z.posi+20),string(z.posi+40),string(z.posi+60),string(z.posi+80),string(z.posi+100),string(z.posi+120),string(z.posi+140),string(z.posi+160),string(z.posi+180),string(z.posi+200),string(z.posi+220),string(z.posi+240)];
z.h1.x_ticks=tlist(['locations','labels'],[0,40,80,120,160,200,240,280,320,360,400,440,480],[z.xa]);
//////////
z.h1.z_ticks=tlist(['locations','labels'],[0,100,200,300,400,500,600,700,800,900,1000],["0","0.1","0.2","0.3","0.4","0.5","0.6","0.7","0.8","0.9","1"+' V= '+string(z.verstaerkung)]);
//
set(u72,'value',z.posi); // laufzeitwert value in formular play spinner

case 5 //480
//z.xa=[string(z.posi-1),string(z.posi+79),string(z.posi+159),string(z.posi+239),string(z.posi+319),string(z.posi+399),string(z.posi+479)];
z.xa=[string(z.posi),string(z.posi+30),string(z.posi+60),string(z.posi+90),string(z.posi+120),string(z.posi+150),string(z.posi+180),string(z.posi+210),string(z.posi+240),string(z.posi+270),string(z.posi+300),string(z.posi+330),string(z.posi+360),string(z.posi+390),string(z.posi+420),string(z.posi+450),string(z.posi+480)];

z.h1.x_ticks=tlist(['locations','labels'],[0,30,60,90,120,150,180,210,240,270,300,330,360,390,420,450,480],[z.xa]);
//////////
z.h1.z_ticks=tlist(['locations','labels'],[0,100,200,300,400,500,600,700,800,900,1000],["0","0.1","0.2","0.3","0.4","0.5","0.6","0.7","0.8","0.9","1"+' V= '+string(z.verstaerkung)]);
//
set(u72,'value',z.posi); // laufzeitwert value in formular play spinner
end
endfunction
/////////////////////////////////////////////////////////////////////////
function [z]=titeledit(z)
//
z.ti=x_dialog('Titel eingeben',z.ti);
title(z.ti,'fontsize',3);
endfunction
/////////////////////////////////////////////////////////////////////////
/////////     S T A R T      //////////////////////////////////////
///////////////////////////////////////////////////////////////////
// Formular erstellen
z.f=figure('position',[10,10,1400,900]);

//z.f.axes_size = [1800,874]
z.f.auto_resize = "on"
z.f.viewport = [0,0]
//z.f.figure_name = "Grafik-Fenster Nummer %d"
//z.f.figure_id = 0
z.f.info_message = ""
//cm=load('D:\Scilab\cm.dat')
//z.cm=cm;
//z.f.color_map = z.cm;
z.f.pixel_drawing_mode = "copy"
z.f.anti_aliasing = "off"
z.f.immediate_drawing = "on"
z.f.background =  -2
z.f.visible = "on"
z.f.rotation_style = "unary"
//z.f.event_handler = ""
//z.f.event_handler_enable = "off"
z.f.user_data = []
z.f.resizefcn = ""
z.f.closerequestfcn = ""
z.f.resize = "on"
//z.f.toolbar_visible = "on"
z.f.dockable = "on"
//z.f.layout = "none"
//z.f.layout_options = "OptNoLayout"
z.f.default_axes = "on"
z.f.icon = ""
z.f.tag = ""


//'0 %          480s|50 %        240s|75 %        120s|87,5 %       60s|93,75 %     30s'

// controls in das Formular einbauen
////////////////////////////////////voreinstellungen
// seitentext
u11=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'backgroundcolor',[0.1 1 0.8],'position', [1310 870 80 20],'string','1 bis '+string(z.fo1)+' Hz');
//verstärkung
u21=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'backgroundcolor',[0.1 1 0.8],'position', [1310 840 80 20],'string','Verstärkung');
u22=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'position', [1310 810 40 30],'string','0');
u23=uicontrol(z.f,"style","spinner", 'position', [1350 810 40 30],'HorizontalAlignment','center','VerticalAlignment','middle','min',1,'max',10,'SliderStep',[1,10],'Title_position','top','callback','');
//kanalwahl
u31=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'backgroundcolor',[0.1 1 0.8],'position', [1310 775 80 20],'string','Kanalwahl');
u32=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'position', [1310 745 40 30],'string','0');

u33=uicontrol(z.f,"style","spinner", 'position', [1350 745 40 30],'HorizontalAlignment','center','VerticalAlignment','middle','min',1,'max',1,'SliderStep',[1,10],'Title_position','top','callback','');
//position der berechnung
u41=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'backgroundcolor',[0.1 1 0.8],'position', [1310 710 80 20],'string','Position Sek.');
u42=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'position', [1310 690 80 20],'string','0');
u43=uicontrol(z.f,"style","spinner", 'position', [1310 660 80 30],'HorizontalAlignment','center','VerticalAlignment','middle','min',0,'max',0,'SliderStep',[1,10],'Title_position','top','callback','');
z.posi=u43.value
////darstellung
u46=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'backgroundcolor',[0.1 1 0.8],'position', [1310 625 80 20],'string','Darstellung');
u47=uicontrol(z.f,"style","radiobutton",'groupname','darst','HorizontalAlignment','left','position', [1310 605 80 20],'string','FFT','callback','z.darst=1;[z]=malen0(z)');
u48=uicontrol(z.f,"style","radiobutton",'groupname','darst','HorizontalAlignment','left','position', [1310 585 80 20],'string','Power','callback','z.darst=2;[z]=malen0(z)');
u47.value=1;
//zoom
u51=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'backgroundcolor',[0.1 1 0.8],'position', [1310 550 80 20],'string','Zoom Frequenz');
u52=uicontrol(z.f,"style","spinner", 'position', [1310 520 80 30],'HorizontalAlignment','center','VerticalAlignment','middle','min',1,'max',250,'SliderStep',[1,10],'Title_position','top','callback','');
u52.value=250;
u53=uicontrol(z.f,"style","pushbutton","Relief", "raised",'HorizontalAlignment','center' ,'position', [1310 490 80 20],'string','Zoom Grafik','callback','z.h1.zoom_box=[0,0,480,u52.value]');
//titel
u54=uicontrol(z.f,"style","pushbutton",'Relief','raised','HorizontalAlignment','center' ,'position', [1310 460 80 20],'string','Titel Edit','callback','[z]=titeledit(z)');
//savegrafik
u55=uicontrol(z.f,"style","pushbutton","Relief", "raised",'HorizontalAlignment','center' ,'position', [1310 430 80 20],'string','Save Grafik','callback','[z]=savgif1(z)');
// überdeckung
//'93,75 %     30s|87,5 %       60s|75 %        120s|50 %        240s|0 %          480s'
z.uliste=['93,75 %     30s' '87,5 %       60s' '75 %        120s' '50 %        240s' '0 %          480s']
u61=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'backgroundcolor',[0.1 1 0.8],'position', [1310 395 80 20],'string','Überdeckung');
u62=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'position', [1310 375 80 20],'string',z.uliste(1));
u63=uicontrol(z.f,"style","listbox",'string',z.uliste,'position', [1310 290 80 85],'HorizontalAlignment','center','VerticalAlignment','middle','Title_position','top','callback','');
u63.value=1;
//samplefrequenz
u64=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'backgroundcolor',[0.1 1 0.8],'position', [1310 255 80 20],'string','Samplefrequenz');
u65=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'position', [1310 235 80 20],'string','0');
///start
u70=uicontrol(z.f,"style","pushbutton","Relief", "raised",'HorizontalAlignment','center' ,'position', [1310 200 80 20],'string','Start','callback','[z]=starten1(z)');
//position play
u71=uicontrol(z.f,"style","text",'HorizontalAlignment','center' ,'backgroundcolor',[0.8 0.5 0.5],'position', [1310 160 80 20],'string','Playposition');
u72=uicontrol(z.f,"style","spinner", 'position', [1310 130 80 30],'HorizontalAlignment','center','VerticalAlignment','middle','min',0,'max',1,'SliderStep',[1,10],'Title_position','top','callback','');
z.spiel1=u72.value
u73=uicontrol(z.f,"style","pushbutton","Relief", "raised",'backgroundcolor',[0.8 0.5 0.5], 'position', [1310 90 80 25],'string','Play 10 Sek.','callback','[z]=abspielen(z)');
///dateianzeige unten
// Dateianzeige
u81=uicontrol(z.f,"style","text",'FontWeight','bold','HorizontalAlignment','left' ,'position', [50 10 700 20],'string','');
u82=uicontrol(z.f,"style","text",'FontWeight','bold','HorizontalAlignment','left' ,'position', [800 10 300 20],'string','');
// Neu
u98=uicontrol(z.f,"style","pushbutton","Relief", "raised",'backgroundcolor',[0.8 0.5 0.5], 'position', [1310 50 80 25],'string','Neu','callback','[z]=neu(z)');
// Exit
u99=uicontrol(z.f,"style","pushbutton","Relief", "raised", 'backgroundcolor',[0.8 0.5 0.5],'position', [1310 10 80 25],'string','Exit','callback','close');


u999a=uicontrol(z.f,"style","text",'backgroundcolor',[0.1 1 0.8],'position', [1392 200 10 690],'string','');
u999b=uicontrol(z.f,"style","text",'backgroundcolor',[0.1 1 0.8],'position', [1392 90 10 90],'string','');
u999c=uicontrol(z.f,"style","text",'backgroundcolor',[0.1 1 0.8],'position', [1392 10 10 65],'string','');

////////////////////////////////////////////////////////////
[z]=achsenx1(z)
//////////////////////////////////////garphicfenster einbauen
z.h1 = newaxes(); // 
z.h1.axes_bounds = [-0.05,-0.05,1.17,1.05];
///////////////////////////////////////////////beschriftung x achse
///////////////////////////////////////////////
sca(z.h1)
z.h1.visible = "on"
z.h1.axes_visible = ["on","on","on"]
z.h1.axes_reverse = ["on","off","off"]
z.h1.grid = [1,1,1]
z.h1.grid_position = "background"
z.h1.grid_thickness = [1,1,1]
z.h1.grid_style = [1,1,1]
z.h1.x_location = "bottom"
z.h1.y_location = "left"
z.h1.auto_ticks = ["off","off","off"]
z.h1.z_ticks=tlist(['locations','labels'],[0,100,200,300,400,500,600,700,800,900,1000],["0","0.1","0.2","0.3","0.4","0.5","0.6","0.7","0.8","0.9","1"+' V= '+string(z.verstaerkung)]);
z.h1.y_ticks=tlist(['locations','labels'],[0,10,20,30,40,50,60,70,80,90,100,110,120,130,140,150,160,170,180,190,200,210,220,230,240,250],["0","10","20","30","40","50","60","70","80","90","100","110","120","130","140","150","160","170","180","190","200","210","220","230","240","250"]);
z.xa=[string(z.posi),string(z.posi+30),string(z.posi+60),string(z.posi+90),string(z.posi+120),string(z.posi+150),string(z.posi+180),string(z.posi+210),string(z.posi+240),string(z.posi+270),string(z.posi+300),string(z.posi+330),string(z.posi+360),string(z.posi+390),string(z.posi+420),string(z.posi+450),string(z.posi+480)];

z.h1.x_ticks=tlist(['locations','labels'],[0,30,60,90,120,150,180,210,240,270,300,330,360,390,420,450,480],[z.xa]);

//z.h1.x_ticks=tlist(['locations','labels'],[0,40,80,120,160,200,240,280,320,360,400,440,480],["0","5","10","15","20","25","30",'35','40','45','50','55','60']);
//z.h1.x_ticks=tlist(['locations','labels'],[0,40,80,120,160,200,240,280,320,360,400,440,480],[z.xa]);
z.h1.ticks_format = ["","",""]
z.h1.ticks_st = [1,1,1;0,0,0]
z.h1.box = "back_half"
z.h1.filled = "on"
z.h1.sub_ticks = [9,9,9]
z.h1.font_style = 6
z.h1.font_size = 2
z.h1.font_color = -1
z.h1.fractional_font = "off"

z.h1.title.font_size=2;
//z.h1.title.text=z.pfaddatei;
z.h1.x_label.font_size=2;
z.h1.x_label.text="Sekunden";
z.h1.x_label.visible="on";
z.h1.y_label.font_size=2;
z.h1.y_label.text="Frequenz";
z.h1.y_label.visible="on";
z.h1.z_label.font_size=2;
z.h1.z_label.text="Amplitude";
z.h1.z_label.visible="on"; 
//z.h1.legend=z.pfaddatei; 
 
z.h1.isoview = "off"
z.h1.cube_scaling = "on"
z.h1.view = "3d"
z.h1.rotation_angles = [10,-10]
z.h1.log_flags = "nnn"
z.h1.tight_limits = ["on","on","on"]

z.h1.zoom_box = []
z.h1.auto_margins = "off"
z.h1.margins = [0.07,0.165,0.08,0.11]
z.h1.axes_bounds = [-0.05,-0.05,1.17,1.05]
z.h1.auto_clear = "off"
z.h1.auto_scale = "off"
z.h1.hidden_axis_color = 4
z.h1.hiddencolor = 4
z.h1.line_mode = "on"
z.h1.line_style = 1
z.h1.thickness = 1
z.h1.mark_mode = "off"
z.h1.mark_style = 0
z.h1.mark_size_unit = "tabulated"
z.h1.mark_size = 0
z.h1.mark_foreground = -1
z.h1.mark_background = -2
z.h1.foreground = -1
z.h1.background = -2
z.h1.arc_drawing_method = "lines"
z.h1.clip_state = "off"
//z.h1.clip_box = []
z.h1.user_data = []
z.h1.tag = ""
zh(1,3)=0;// Amplitude
zh(2,3)=1000;// Amplitude
zh(1,2)=0;// Frequenz
zh(2,2)=250;// Frequenz
zh(1,1)=0;// Zeit
zh(2,1)=480;//Zeit
z.h1.data_bounds =zh;

/////////////////////////////////////////////////////////////////////////
//////////////////////////////////////////////////////////////////////////
////farbe
for i=1:1200
    cm(i,:)=[0 0 0]
end
cm(1:150,:)=jetcolormap(150)
for i=130:1200 
    cm(i,:)=[1 0.2 0]
end
z.cm=cm(30:1030,:);
cmm=[0 0 0.2]
z.cm(100,:)=cmm;
z.cm(200,:)=cmm;
z.cm(300,:)=cmm;
z.cm(400,:)=cmm;
z.cm(500,:)=cmm;
z.cm(600,:)=cmm;
z.cm(700,:)=cmm;
z.cm(800,:)=cmm;
z.cm(900,:)=cmm;
//z.cm=jetcolormap(1000)
z.f.color_map = z.cm;
///////////////////////////////////////////